Writing User-Defined Functions

When an OLAP DML program returns a value, it is called a user-defined function. You can use it in commands and expressions.

A user-defined function contains a RETURN command followed by an expression.

RETURN expression

The RETURN command returns a single value when the program terminates.

Data Type of a User-Defined Function

When you create a user-defined function, you define the program with a data type or dimension name, using the following syntax of the DEFINE command.

DEFINE programname PROGRAM [datatype|dimension]

The datatype argument specifies the data type of the value to be returned by the program when it is called as a function.

The dimension argument specifies the name of a dimension whose value the program returns when it is called as a function. The return value will be a single value of the dimension, not a position (integer). The dimension must be defined in the same analytic workspace as the program. The value that is returned by the program has the data type that is specified in the definition. If you specify a dimension name, then the program returns a value of that dimension.

The return expression in the program should match the data type that is specified in its definition. If the data type of the return value does not match the data type that is specified in its definition, then the value is converted to the data type in the definition.

If you do not specify a data type for the program, then the return value is converted to the data type that is required by the caller.

Arguments in a User-Defined Function

User-defined functions can accept arguments. A user-defined function returns only a single value. However, if you supply an argument to a user-defined function in a context that loops over a dimension (for example, in a REPORT command), then the function returns results with the same dimensions as its argument.

You must declare the arguments using the ARGUMENT command within the program, and you must specify the arguments in parentheses following the name of the program.

Example 7-6 User-Defined Function

Suppose your analytic workspace contains a variable called units.plan, which is dimensioned by the product, district, and month dimensions. The variable holds integer data that indicates the number of product units that are expected to be sold.

Suppose also that you define a program named units_goals_met. This program is a user-defined function. It accepts three dimension-value arguments that specify a given cell of the units.plan variable, and it accepts a fourth argument that specifies the number of units that were actually sold for that cell. The program returns a Boolean value to the calling program. It returns YES when the actual figure comes up to within 10 percent of the planned figure; it returns NO when the actual figure does not.

The definition of the units_goals_met program is listed below.

DEFINE units_goal_met PROGRAM BOOLEAN
LD Tests whether actual units met the planned estimate
"Program Initialization
ARGUMENT userprod  TEXT
ARGUMENT userdist  TEXT
ARGUMENT usermonth TEXT
ARGUMENT userunits integer
VARIABLE answer boolean
TRAP ON errorlabel
PUSH product district month
"Program Body
LIMIT product TO userprod
LIMIT district TO userdist
LIMIT month TO usermonth
IF (units.plan - userunits) / units.plan GT .10
   THEN answer = NO
   ELSE answer = YES
"Normal Exit
POP product district month
RETURN answer
"Abnormal Exit
errorlabel:
POP product district month
SIGNAL errorname errortext
END

To execute the units_goal_met program and store the return value in a variable called success, you can use an assignment statement.

success = units_goal_met('TENTS' 'BOSTON' 'JUN96' 2000)